Category: Робот манипулятор

July 11, 2019 finereader No comments exist

Робот манипулятор. Собираем готовый проект

 

Программная часть готового проекта :

  • код для платы Arduino, получающей по COM-порту от компьютера пакет с тремя углами поворота серводвигателей
  • программа в среде Processing, работающая на ПК, которая сначала определяет координаты мишени (обрабатывая изображение с камеры), а затем рассчитывает углы для Arduino

 

 

Только для начала, было бы неплохо отработать всю систему без камеры, просто указывая координаты мышкой на экране. Для этого и предназначена вот эта программа для Processing. Работает с той же программой для Arduino.

July 11, 2019 finereader No comments exist

Робот манипулятор. Техническое зрение

В нашем проекте по созданию робота мы уже разработали кинематику движения, конструкцию звеньев и алгоритм движения.

Система управления робота, выполняющая наш алгоритм, рассчитает углы поворота звеньев если мы дадим ей координаты точки, в которую необходимо привести схват робота.

Робот будет охотиться за мишенями характерного цвета, помещенными в его рабочую зону.

Повесим веб-камеру над рабочей зоной, в Processing захватим видео с этой камеры.

Обработка в Processing будет представлять чтение изображения с камеры несколько раз в секунду, а затем выделения пикселей требуемого цвета. Найдя все подходящие пиксели, зная их координаты, определим “центр масс” всей фигуры – это и есть точка, целеуказание для робота.


/*Программа реализует захват изображения 
с камеры и определение объекта цветовым фильтром
в пространстве HSB (в нем намного удобнее сравнивать объекты,
чем в RGB-пространстве)
Выбор цвета для работы фильтра производится указанием
мыши на пиксель*/

import processing.video.*;

Capture cam;
   
   //Переменные для хранения выбранного цвета
   float huesel = 0.0; //Оттенок цвета
   float satsel = 0.0;
   float brsel = 0.0;
  
  //Переменные для расчета центра фигуры
  int ii=0; //счетчик найденных пикселей
  float sumX=0.0; //сумма Х-координат найденных пикселей выбранного цвета
  float sumY=0.0; //сумма Y-координат найденных пикселей выбранного цвета

int w=320; //640
int h=240; //480

void setup() {
  
  size(320, 240);
  //size(640, 480);
  String[] cameras = Capture.list();

  if (cameras == null) {
    println("Failed to retrieve the list of available cameras, will try the default...");
    cam = new Capture(this, w, h);
  } if (cameras.length == 0) {
    println("There are no cameras available for capture.");
    exit();
  } else {
    println("Available cameras:");
    printArray(cameras);
    
    //Интерфейс камеры с нужным разрешением(320х240)
   // cam = new Capture(this, cameras[9]);
    cam = new Capture(this, cameras[12]);
    cam.start();
  }
}

void draw() {
  //Захватываем изображение с камеры
  if (cam.available() == true) {
    cam.read();
  }
  
  //Выводим изображение в окно
  image(cam, 0, 0, width, height);
  
  //Пробегаем по всем пикселям изображения
  ii=0; sumX=0.0; sumY=0.0;
  for (int i=0;i<w;i+=1){
    for(int j=0; j<h;j+=1){
       //получаем цвет текущего пикселя
       color cc = get(i,j);
       //и переводим его в HSB-пространство
       float h = hue(cc);
       float s = saturation(cc);
       float br = brightness(cc);
       //Сравниваем тек. пиксель с выбранным с учетом 
       //некоторого допуска на отличие в цвете
        if (h<=(huesel+15) && h>=(huesel-15) &&
            s<=(satsel+15) && s>=(satsel-15) &&
            br<=(brsel+150) && br>=(brsel-150))
        {    
          //добавляем координату к общей сумме
          sumX+=i;
          sumY+=j;
          ii++;   
          //делаем найденный пиксель красным
          color cch = color(255,0,0);
          set(i,j,cch); //set(i,j-1,cch);set(i-1,j-1,cch);
        }

    }
  }
  
  //вычисляем центр фигуры из найденных пикселей
  float cX = sumX/ii;
  float cY = sumY/ii;
  
  //рисуем перекрестие
  strokeWeight(5);
  stroke(255,0,0);
  point(cX,cY);
    strokeWeight(1);
    line(cX,0,cX,height);
    line(0,cY,width,cY);
  
  //перевод координат в мм
  float cXmm = cX*167/320;
  float cYmm = cY*125/240;
  fill(230,0,0);
  text("X"+" "+cXmm,width-50,20);
  text("Y"+" "+cYmm,width-50,40);
  
  //Запись кадров
 //saveFrame("frames2/####.tiff");  
}

//обработчик указания мыши - захват цвета указанного пикселя
void mouseClicked(){
  color col = get(mouseX,mouseY);
  huesel = hue(col);
  satsel = saturation(col);
  brsel  = brightness(col);
}

 

Сама обработка захваченной картинки (функция draw() ) заключается в обходе всех пикселей в двойном цикле for. Внешний цикл по столбцам по координате Х экрана – перебираем все по счетчику i от нулевого до ширины экрана width.

Внутренний цикл по координате Y перебирает все пиксели данного столбца (выбранного во внешнем цикле) двигаясь по счетчику j от нулевой строки до height.

Получить цвет пикселя можно по его координатам на экране функцией get(i,j)

Сравнивая цвет текущего пикселя с заданным цветом, в блоке if решаем, принадлежит этот пиксель к выбранной мишени или нет. 

 

Функция mouseclicked() нужна для указания требуемого цвета.

Используемая кодировка цвета – HSB. В этой кодировке собственно оттенок цвета задан первым значением, по которому удобно сравнивать пиксели.

 

Центр фигуры определяется как отношение суммы координат точек к их числу.

 

В конце надо только не забыть рассчитать смещение координат. В Processing координаты отсчитываются от верхнего левого угла и координаты мишени для робота необходимо пересчитать, так как ноль координат в системе робота был в центре его основания.

 

 

December 16, 2018 finereader No comments exist

Робот манипулятор. Алгоритм управления

 

  • robmodel2
  • robmodel1

Создадим систему управления роботом и разработаем алгоритм управления его движением.

 

Задача системы управления (СУ) – определять ошибку между требуемым и текущим положениями схвата робота, рассчитывать перемещения отдельных звеньев и выдавать управляющий сигнал на серво-двигатели.

 

Наша СУ будет состоять из сервоприводов (SG-90), платы Arduino и ПК с программой, получающей координаты цели и рассчитывающей требуемые углы поворота серв.

Общий алгоритм управления Роботом такой:

  • Определить требуемое положение схвата: схват должен придти в точку цели. Цель можно указать мышкой, написав программу на компьютере (например в Processing) или обработать изображение с камеры, висящей над рабочей зоной робота, выделив на нем объект нужного цвета или формы.

  • Рассчитать требуемые положения звеньев робота, т..е. углы поворота двигателей. Ввиду простоты схемы робота, сильно напоминающей треугольник, нам понадобятся некоторые знания геометрии (теорема Пифагора, синусы, теорема косинусов). В нашей программе на Processing, определив координаты цели, сразу же рассчитаем и все углы, высвобождая этим ресурсы Arduino.

  • Передача рассчитанных требуемых углов в Arduino. А дальше есть библиотека Servo и команда Servo::write(угол). Но попытка просто использовать эту функцию может привести к тому, что в случае требования повернуться на большой угол (например 180 град), серво-двигатель попытается мгновенно придти в указанное положение. Робот имеет некоторую массу и обладает инерцией, а это значит, что он будет сопротивляться изменению своей скорости. Силы инерции могут сорвать зубья шестеренок сервы. Необходимо попытаться сгладить переход между положениями, растянув его во времени.

Разобьем весь переход на несколько временных шагов и на каждом будем двигаться на долю, пропорциональную (составляющую часть) ошибке: Kp*error. Это еще называется пропорциональный регулятор (П-регулятор). 

 

Итак, микроконтроллер, получив значение требуемого угла поворота, рассчитает ошибку положения (текущее положение доступно из Servo::read()) и за некоторое количество тактов плавно переместит робота. От коэффициента пропорциональности зависит плавность.

 

 

Сейчас о том, как рассчитать требуемые положения звеньев робота.

Тут понадобятся базовые знания геометрии о прямоугольном треугольнике, соотношении его сторон в теореме Пифагора, откуда берутся синусы и косинусы. 

Сведения из геометрии

  • sin1
  • sin2
  • sin3
  • sin4
  • sin5
  • sin6
  • sin7

Программа на Processing с наглядной демонстрацией того, что sin(А) – это просто средство расчета противолежащего углу А катета.

 

 

Робот имеет 3 степени свободы (3 цилиндрических шарнира – 3 оси вращения), что позволяет перемещаться схвату по трем координатам xyz, но мы ограничимся плоскостью xy. 

На виде в плане (сверху то есть) мы видим схему робота и точку положения мишени с координатами xy, которые нам известны. Зная координаты, рассчитываем общий вылет робота – С (гипотенуза = сумме квадратов катетов). Угол поворота основания рассчитывается как дуга, соответствующая sin (y/c).

 

Робот_расчет1

Робот_расчет2

 

На профильном виде А-А, соединив точки центров серв и схвата, получим треугольник со сторонами L1 L2 R. Длина стороны R рассчитывается из прямоугольного треугольника СhR (где h-высота основания робота).

Но как быть с треугольником L1 L2 R- все стороны мы знаем, а углы нет. Оказывается, в любом треугольнике, имея длины его сторон можно найти его углы по теореме косинусов (или сторону, лежащую напротив известного угла, образованного двумя известными сторонами).

 

 

 

Теперь напишем модель робота в среде Processing и протестируем алгоритм.

Программа, как и Arduino, должна иметь две обязательные функции – setup() и draw(бесконечный цикл).

 

Создаем глобальные переменные для хранения размеров звеньев робота и текущих углов поворота этих звеньев, а также окно 800х600:

 

/* Переменные с размерами робота*/
float c = 0.0;  //вылет робота
float h = 80;   //высота основания
float L1 = h*3; //плечо
float L2 = h*4; //предплечье

/* Переменные с углами робота*/
  float alfa;
  float Beta,Beta2;
  float gamma;
  float tau,tau2;

void setup(){
  size(800,600,P3D);
}

 

В функции draw() на каждом такте перерисовки экрана :

 – отображаем мишень по координатам мыши

 – переносим систему координат в удобное место для отрисовки первого звена (основания)

 – рассчитываем положения звеньев робота

 – отрисовываем звенья основания, плеча и предплечья (с поочередным переносом систем координат)

 

void draw(){
  
  //Очищаем окно
  //background(#EAD5D5);

  /*Рисуем цель-мишень по координатам мыши*/
  drawTarget();
  
  //Перенос системы координат
  //и поворот
  //Y /\
  //X >>>
  translate(width/4,height/2+height/4);
  rotateX(radians(180));
  
  /* Рассчитываем положение робота - углы*/
  computeRobotpos();
  
  //Рисуем Основание Робота
  drawBase();
  
  //Рисуем Плечо Робота
  drawArm();

  //Рисуем Предплечье Робота
  drawForeArm();
}

 

 

Функция расчета положений звеньев – computeRobotpos() – смотри картинку выше

 

void computeRobotpos(){
  //Вылет Робота
  float c = (mouseX-width/4);
  float R = sqrt(h*h + c*c);
   alfa = asin(h/R);
   Beta = acos( (L1*L1 + L2*L2 - R*R) / (2*L1*L2));
   gamma = acos( (L1*L1 + R*R - L2*L2) / (2*L1*R));
   tau = gamma - alfa;
}

 

 

Функции отрисовки звеньев нехитрым образом переносят СК в точку начала следующего звена, поворачивают её на рассчитанный угол и командой line() чертят линию вдоль оси Х, по длине совпадающую с длиной данного звена:

 

void drawBase(){
  //Точка центра
  strokeWeight(3);
  stroke(255,255,0);
  point(0,0);
  
    strokeWeight(3);
    stroke(255,255,0);
  line(0,0,0,h);
    strokeWeight(15);
    point(0,h);
  drawlocalCS();
}

void drawArm(){
  //переносим систему координат
  //в точку начала звена
  translate(0,h);
  rotateZ((tau));
  
    strokeWeight(3);
    stroke(255,255,0);
  line(0,0,L1,0);
    strokeWeight(15);
    point(L1,0);
  drawlocalCS();
}

void drawForeArm(){
  //переносим систему координат
  //в точку начала звена
  translate(L1,0);
  rotateZ(-(PI-Beta));
  
    strokeWeight(3);
    stroke(255,255,0);
  line(0,0,L2,0);
    strokeWeight(15);
    point(L2,0);
  drawlocalCS();
}

 

 

November 23, 2018 finereader No comments exist

Робот-манипулятор. Производственное

 

Для подготовки печати деталек робота использовалась программа Cura 14.

Собственно, ничего особенно настраивать не надо, да и программа в G-коде с нужными траекториями проходов по нарезанным слоям генерируется автоматически самой средой Cura.

 

Технология печати такова, что сначала печатаются внешний и внутренние замкнутые контуры (оболочки), а между ними пространство детали заполняется относительно редкой сеткой. И так слой за слоем. Необходимо только указать базовые настройки печати:

– толщина слоя Layer height (брали 0,2 мм для грубой и 0,1 мм для тонкой печати)

– толщина оболочки детали Shell thickness (0,8 мм в основном)

– толщины нижнего/верхнего слоев Bottom/Top thickness (0,8 мм не всегда достаточно, можно и 1,2 мм)

– заполнение Fill density (30 – 45%)

– скорость печати Print speed (сначала была 60 мм/с, уменьшили до 15-20 мм/с, немного выросло качество печати)

– температура печати т. е. сопла Printing temperature (для PLA-пластика 200 гр С)

– температура стола Bed temperature (50 гр С для PLA-пластика)

 

  • shaft8set
  • forearmset
  • pinceset
  • armset
  • basesetting

Сборка, тоже технологический процесс

  • IMG-20181115-WA0003
  • IMG-20181115-WA0000
  • IMG-20181115-WA0010
  • IMG-20181115-WA0008
  • IMG-20181115-WA0007
  • IMG-20181115-WA0006

November 1, 2018 finereader No comments exist

Робот-манипулятор. Конструируем

 

Робот_кин

 

Добрались, наконец, до первого серьёзного (без кавычек) проекта в группе Ардуино (продолжающие). Делаем роборуку или робота-манипулятора

 

Поставили себе с учениками задачу – конструируем робота. Робот должен уметь хватать объекты-мишени на плоскости. Зона обслуживания – сектор в 180 градусов.

 

Определять координаты мишени можно будет сначала прямым указанием (создадим программу на компьютере в среде Processing, где мышкой можно будет указать точку в рабочей зоне), ну а следующий шаг – подключим веб-камеру и будем обрабатывать изображение с помощью цветового фильтра, который позволит выделить мишень характерного цвета для определения её координат.

 

Начнем с кинематической схемы и конструкции робота

 

Нарисовали схему с тремя степенями свободы — с ней проще будет рассчитать кинематику движения в дальнейшем (обойдемся теоремой косинусов) — собственно, есть звенья плеча и предплечья, а также схват. Ну и поворачивается вся эта конструкция на пятке

 

Нижнюю опору с пяткой решили сделать с настоящим металлическим подшипником (будет служить дополнительной опорой и не даст нагрузке срезать валик на нижнем серводвигателе), все остальные детали будем печатать на 3D-принтере

 

Для начала мне пришлось подготовиться к занятию и набросать эскизы деталек и сборки в САПР Компас (на самом деле это переросло в создание альбома чертежей):

 

  • Манипулятор0004
  • Манипулятор0003
  • Манипулятор0005
  • Манипулятор0001
  • Манипулятор0002

Для создания по этим чертежам 3D моделек использовали FreeCAD. Это параметрическая САПР, довольно удобная, с большими яркими кнопками (что для обучения таким рисовалкам, наверное, главное), даже модуль сборки есть. Там же можно создать и файлы сетки *.stl для 3D-принтера

 

 

Вот, собственно, напечатанное и собранное основание будущего робота:

 

  • IMG_20181021_135716
  • IMG_20181020_181238
  • IMG_20181021_135724

 

В итоге, получается вот что

  • IMG_20181118_135940
  • IMG_20181118_133551
  • IMG_20181118_133309
  • IMG_20181118_133358

 

Вообще, с простой программой моделирования типа FreeCAD и 3D-принтером под рукой открываются большие возможности для получения быстрого результата и материализации мыслей, что особенно радовало моих учеников